Экспонента от бикватерниона

Оператор группы Лоренца

Еще одна техническая задача, которую необходимо выполнить, это построение экспоненты от бикватерниона, поскольку полуоператоры являются экспонентами от параметров.

Для этого используем те же действия, что использовал Эйлер для построения формулы экспоненты от комплексного числа. А именно, раскроем экспоненциальный ряд для аргумента - мнимого кватерниона. Если обозначить через ${\bf n}$ единичный вектор направления аргумента, то $$ ix_1+jx_2+kx_3 = {\bf n}\sqrt{x_1^2+x_2^2+x_3^2} $$ Единичный вектор ${\bf n}$ имеет те же свойства что и мнимая единица $i$ в разложении в экспоненцильный ряд: $$ {\bf n}^2= -1 $$ Соответственно, в таких обозначениях экспонента от мнимого кватерниона имеет тот же вид, что и в формуле Эйлера: $$ e^{ix_1+jx_2+kx_3} = \cos(\sqrt{x_1^2+x_2^2+x_3^2})+ {\bf n}\sin(\sqrt{x_1^2+x_2^2+x_3^2}) $$ В нашей задаче используются не кватернионы, а бикватернионы. И вместо мнимой части из 3-х компонент кватерниона $$ ix_1+jx_2+kx_3 $$ используется мнимая часть из пары 3-х компонентных векторов, или бивектор: $$ Iix_1+Ijx_2+Ikx_3+ix_5+jx_6+kx_7 $$ Это часть полного бикватерниона с отсутствующими (или нулевыми) скалярной и псевдоскалярной частями.

Мы можем сгруппировать компоненты бикватернионного бивектора так, чтобы получить векторную часть комплексного кватерниона: $$ i(x_5+Ix_1)+j(x_6+Ix_2)+k(x_7+Ix_3) $$ То есть получили кватернионную часть но преобразовав её коэффициенты из действительных в комплексные с мнимой единицей не относящейся к набору $ijk$. Поскольку псевдоскалярная единица $I$ коммутирует со всеми единицами бикватернионов, можем подставить результаты группировки в формулу экспоненты от кватерниона: $$ {\bf n} = \frac{i(x_5+Ix_1)+j(x_6+Ix_2)+k(x_7+Ix_3)} {\sqrt{(x_5+Ix_1)^2+(x_6+Ix_2)^2+(x_7+Ix_3)^2}} $$ $$ \begin{array}{c} e^{i(x_5+Ix_1)+j(x_6+Ix_2)+k(x_7+Ix_3)} = \\ = \cos(\sqrt{(x_5+Ix_1)^2+(x_6+Ix_2)^2+(x_7+Ix_3)^2})+ \\ + {\bf n}\sin(\sqrt{(x_5+Ix_1)^2+(x_6+Ix_2)^2+(x_7+Ix_3)^2}) \end{array} $$ Раскрытие функций косинус и синус комплексных чисел, равно как и корня комплексного числа в их аргументе и в знаменателе, передадим системе компьютерной алгебры Maxima. Опишем функцию, которая вычисляет используя параметры корень, синус, косинус и выделяет из полученных выражений действительную и мнимую части, попутно проводя возможные упрощения:

makeexp(x1,x2,x3,x5,x6,x7):=
(
  Fsqrt:sqrt((x5+%i*x1)^2+
    (x6+%i*x2)^2+(x7+%i*x3)^2),
  Fsin:sin(Fsqrt),
  Fcos:cos(Fsqrt),
  [
    ratsimp(realpart(Fcos)),
    ratsimp(imagpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(imagpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(imagpart(Fsin/Fsqrt*(x7+%i*x3))),
    ratsimp(imagpart(Fcos)),
    ratsimp(realpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(realpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(realpart(Fsin/Fsqrt*(x7+%i*x3)))
  ]
);

Еще одна техническая задача, которую надо выполнить, это упрощение самой функции взятия экспоненты с заменой на более укороченную запись выражения суммы квадратов: $$ (x_5+Ix_1)^2+(x_6+Ix_2)^2+(x_7+Ix_3)^2\rightarrow\alpha_0+I\alpha_1 $$ Для этого введем еще две функции на основе makeaxp, но в определении функции Maxima сделаем замену:

leftexp(x1,x2,x3,x5,x6,x7):=
(
  Fsqrt:sqrt(alpha[0]+%i*alpha[1]),
  Fsin:sin(Fsqrt),
  Fcos:cos(Fsqrt),
  [
    ratsimp(realpart(Fcos)),
    ratsimp(imagpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(imagpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(imagpart(Fsin/Fsqrt*(x7+%i*x3))),
    ratsimp(imagpart(Fcos)),
    ratsimp(realpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(realpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(realpart(Fsin/Fsqrt*(x7+%i*x3)))
  ]
);

Вызов такой функции будет возвращать бикватернион с коэффициентами, составленными как из $x_i$, так и из синтетической комплексной переменной $$ \alpha=\alpha_0+I\alpha_1 $$ Целью введения такой функции будет сокрытие от системы упрощения Maxima строения переменной $\alpha$, чтобы не предпринималось попыток ее преобразовывать. Поскольку переменная $\alpha$ в действительности есть производная от переменных $x_i$, а они для правого полуоператора передаются в сопряженной форме, саму переменную $\alpha$ придется сопрягать вручную, для этого сделаем еще одну функцию, rightexp:

rightexp(x1,x2,x3,x5,x6,x7):=
(
  Fsqrt:sqrt(alpha[0]-%i*alpha[1]),
  Fsin:sin(Fsqrt),
  Fcos:cos(Fsqrt),
  [
    ratsimp(realpart(Fcos)),
    ratsimp(imagpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(imagpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(imagpart(Fsin/Fsqrt*(x7+%i*x3))),
    ratsimp(imagpart(Fcos)),
    ratsimp(realpart(Fsin/Fsqrt*(x5+%i*x1))),
    ratsimp(realpart(Fsin/Fsqrt*(x6+%i*x2))),
    ratsimp(realpart(Fsin/Fsqrt*(x7+%i*x3)))
  ]
);

В таких опеределениях построение полуоператоров будет выглядеть как:

left:leftexp(psi[x]/2,psi[y]/2,psi[z]/2,
  phi[x]/2,phi[y]/2,phi[z]/2);
right:rightexp(psi[x]/2,psi[y]/2,psi[z]/2,
  -phi[x]/2,-phi[y]/2,-phi[z]/2);

Оператор группы Лоренца